Set a window Always On Top

Question

This AutoHotkey script is related to this post: 
 https://community.sdl.com/product-groups/translationproductivity/f/studio/35337/why-is-the-find-and-replace-window-is-not-always-on-top 
 where the poster asked to set the Find and Replace window on top of the Editor. 
 The following script will set any window Always On Top. It works with any window, not only the Find and Replace dialog box. 
 I use the Application key plus the V keys as a hotkey, but you can change it to your convenience. 
 ☛ The Application Key is also called the Menu Key and when pressed it opens a contextual menu: 
 AppsKey & v:: 
 while GetKeyState("AppsKey", "P") 
 Sleep, 20 
 Winset, Alwaysontop, Toggle, A 
 return 
 Add these lines to your script file and when the Find and Replace window (or any window) is open and active, press the hotkey. From now on the window will be on top on any window, not that just the Editor. And it'll be on top until you close the Find and Replace dialog box or until you press again the same hotkey. 
 
 If you close the Find and Replace dialog box, and re-open it later, you will need to press your hotkey again to set it always on top. 
 If you use another hotkey, you might need to edit the GetKeyState parameter accordingly. 
 
 I hope it helps!

Paul · Answer

Valeria Maria Tafel Jesús Prieto 
 Just a quick update. Valeria and I just had a quick call and we resolved the problem. The correct version of AHK was installed, but the old version of the script (v1) was still in the ahk file in the start folder. We replaced the script and all is well... tested the functionality and that tricky little find/replace window is now happily sitting behind other windows waiting patiently for Valeria to get back to Studio ;-)

Paul · Answer

Valeria Maria Tafel 
 Valeria Maria Tafel said: Can you remind me where I have to put it? 
 You can put it wherever you like! But in your case I recall we put it into the Windows startup folder so that it runs automatically every time you start your computer up. 
 Valeria Maria Tafel said: Just open Autokey and replace all the content I see with this new script above? 
 The easiest way to do this, as you already have a script in place is this: 
 
 Right-Click on the AHK icon in your system tray, and then: 
 
 Select "Edit Script" and this will open in notepad or some editor. Replace the script there with the new one. Just copy paste. Save it! 
 After saving it, close the file and then select "Reload Script" and you're done.

Paul · Answer

Valeria Maria Tafel 
 ok - I tightened up the script a little. The updated version is here: 
 ;------------------------------------------------------------------------------
; Ensure "Find and Replace" window is always on top when Trados Studio is active
; and not always on top when Trados Studio is not active
;------------------------------------------------------------------------------

#Requires AutoHotkey v2.0

global isOnTop := false

$^f:: triggerFindOrReplace("Find")
$^h:: triggerFindOrReplace("Replace")

triggerFindOrReplace(action) {
 global isOnTop
 findTitle := "Find and Replace"

if (action = "Find") {
 Send '^f'
 } else if (action = "Replace") {
 Send '^h'
 }

If WinWaitActive(findTitle " ahk_exe SDLTradosStudio.exe", "", 2) {
 ; Ensure Always on Top when the window is active in Studio
 if !isOnTop {
 WinSetAlwaysOnTop(1, findTitle " ahk_exe SDLTradosStudio.exe")
 isOnTop := true
 }
 }
}

; Check the active window every 100 milliseconds
SetTimer(CheckActiveWindow, 100)

CheckActiveWindow() {
 global isOnTop
 findTitle := "Find and Replace"

if WinActive("ahk_exe SDLTradosStudio.exe") {
 if WinExist(findTitle " ahk_exe SDLTradosStudio.exe") {
 if !isOnTop {
 WinSetAlwaysOnTop(1, findTitle " ahk_exe SDLTradosStudio.exe")
 isOnTop := true
 }
 }
 } else {
 ; If Trados Studio is not active, remove the Always on Top status
 if isOnTop and WinExist(findTitle " ahk_exe SDLTradosStudio.exe") {
 WinSetAlwaysOnTop(0, findTitle " ahk_exe SDLTradosStudio.exe")
 isOnTop := false
 }
 }
} 
 Replace the one you had with this in the same way as before. The new script refines and simplifies the handling of "Find and Replace" window behaviour in relation to Trados Studio. It removes the reliance on the #HotIf directive, directly integrates checks for whether the relevant window is active, and uses a more consistent approach to setting the "Always on Top" status. This makes the script more robust and less dependent on the exact timing or state changes within the application.

Paul · Answer

Valeria Maria Tafel 
 I was testing the "Replace" problem with support in that the Find tab is always active and never the Replace even when clicking Ctrl+H. They could not reproduce this issue. So I revisited the script and made a change so that now it all works correctly: 
 ;------------------------------------------------------------------------------
; Ensure "Find and Replace" window is always on top when Trados Studio is active
; and not always on top when Trados Studio is not active
;------------------------------------------------------------------------------

#Requires AutoHotkey v2.0

; Initialize the global variable
global isOnTop := false

#HotIf WinActive("ahk_exe SDLTradosStudio.exe")

$^f:: triggerFindOrReplace("Find")
$^h:: triggerFindOrReplace("Replace")

triggerFindOrReplace(action) {
 global isOnTop
 find := "Find and Replace" ; Window title of the Find and Replace window

 if (action = "Find") {
 Send '^f'
 } else if (action = "Replace") {
 Send '^h'
 }

 If WinWaitActive(find, "", 2) {
 if !isOnTop {
 WinSetAlwaysOnTop(1, find) ; Set Always-on-Top only once
 isOnTop := true
 }
 }
}

; Check the active window every 100 milliseconds
SetTimer(CheckActiveWindow, 100)

CheckActiveWindow() {
 global isOnTop
 find := "Find and Replace"
 activeWin := WinExist("A")

 ; Add a small delay to ensure the active window is fully registered
 Sleep(100)
 if WinActive("A") != activeWin {
 return ; The active window has changed, do nothing
 }

 if activeWin and WinActive("ahk_exe SDLTradosStudio.exe") {
 if WinExist(find) and !isOnTop {
 WinSetAlwaysOnTop(1, find)
 isOnTop := true
 }
 } else {
 if WinExist(find) and isOnTop {
 WinSetAlwaysOnTop(0, find)
 isOnTop := false
 }
 }
}

#HotIf

Lydia Simplicio · Answer

Thank you- Jes&uacute;s Prieto 
 Im sure users will find this most helpful

Jesús Prieto · Answer

Hi Alexander The Great , 
 The above code works works, but I've confirmed that it doesn't work if I run it in a second AutoHotkey script and I try to set a window on top with both scripts. If I reload the 2nd script, then the 1st one doesn't work. Weird&hellip; 
 Have you got 2 AutoHotkey scripts running? 
 BTW: This is the code I use nowadays: 
 AppsKey & v:: WinGet, ExStyle, ExStyle, A if (ExStyle & 0x8) ; 0x8 is WS_EX_TOPMOST ; ToolTip to show alwaysON enabled else ; ToolTip to show alwaysON disabled Winset, Alwaysontop, Toggle, A 
 return

Paul · Answer

Valeria Maria Tafel 
 I managed to create an AHK version 2 script to solve this which I added to the original post here: 
 RE: Studio 2022 Find/Replace dialog box is always displayed on top 
 All you need to do is install AutoHotkey and add this script to a file called "whateveryoulike.ahk". Then Set this script to run whenever you start your computer. So you have this sort of thing: 
 
 You can get AutoHotKey from here... it's free: 
 https://www.autohotkey.com/ 
 Make sure you Download and install v 2.0 for the script I provided to work.

Paul · Answer

Valeria Maria Tafel 
 That's odd... I would have expected to see it here: 
 C:\Utenti\[NomeUtente]\AppData\Roaming\Microsoft\Windows\Menu Start\Programmi\Avvio 
 Your path is slightly different, but I'm not sure about the way it would look on your system 
 
 Perhaps try typing this in the File Explorer address bar, which should take you directly to the correct folder regardless of your language settings. 
 %APPDATA%\Microsoft\Windows\Start Menu\Programs\Startup 
 If that still doesn't work for you another place you can place this file is here: 
 C:\ProgramData\Microsoft\Windows\Menu Start\Programmi\Avvio 
 ProgramData is a folder for all users on the computer. Any programs or scripts placed in this folder will run for every user who logs into the system as opposed to the one in appdata which will only run for the specified logged in user ([NomeUtente]). 
 See if that's any better.

Alison Field · Answer

Valeria Maria Tafel Paul 
 Sorry to intrude on your conversation, Paul... 
 Have you asked Valeria (in one of her other threads) to make sure 'hidden' folders are visible? 
 
 Just in case not... Valeria, if you look at the above screenshot of my C: drive, the folders that are less bright are the system folders that are hidden if the 'Hidden items' box is not ticked. To be able to see 'ProgramData' for example, that box must be ticked. 
 Sorry if I'm telling you something that you already know... 
 All the best, 
 Ali 
 "Paul Filkin | RWS Group 
 ________________________ Design your own training! You've done the courses and still need to go a little further, or still not clear? Tell us what you need in our Community Solutions Hub "

Paul · Answer

Valeria Maria Tafel 
 Valeria Maria Tafel said: where do I find the online editor? 
 I'm sure I created a video just for you that explained how to find it! Just go here: 
 https://languagecloud.sdl.com/ 
 Login with the same credentials you use for RWS and you'll be able to work entirely online, or if you make sure you either create projects online, or publish Studio projects to the cloud, work in Studio too. 
 I really think this would make a good topic for some training here: Ideas for Free Training I'm quite disappointed that nobody seems bothered to ask for any training, despite the fact it's free, and yet we spend so much time in here trying to show people how to do things. Maybe you can buck the trend!!

Paul · Answer

Valeria Maria Tafel 
 As Jesús Prieto mentioned the script is here: RE: Studio 2022 Find/Replace dialog box is always displayed on top 
 Valeria Maria Tafel said: Do I have to simply copy and paste it? But where? The AutoHotkey file I created does not open... 
 How did you manage to open it before to establish that it was empty? 
 Just navigate to the file and when you get there just right-click on it and open it with your text editor. Then copy/paste that script in there, save it and close it. Then double click the file to initiate it.

Paul · Answer

Valeria Maria Tafel 
 Valeria Maria Tafel said: You know what? Now a window opens up that tells me that the script I am trying to run requires AutoHotkep v.1 ahahahahah! I am totally defeated! 
 There is no doubt in my mind that you have copied the wrong one. I believe you used the link that Jes&uacute;s provided which took you to the top of the thread and then you looked down and took the first one you came to from me which is for V1. If you scrolled to the very next message you would have seen the one from me that was for V2. 
 I gave you a direct link to that post: RE: Studio 2022 Find/Replace dialog box is always displayed on top 
 Please do this again and make sure that you use the correct script. Only this time I am putting the script here as well!! 
 ;------------------------------------------------------------------------------
; Ensure "Find and Replace" window is always on top when Trados Studio is active
; and not always on top when Trados Studio is not active
;------------------------------------------------------------------------------

#Requires AutoHotkey v2.0

#HotIf WinActive("ahk_exe SDLTradosStudio.exe")

$^f:: triggerFindAndReplace()
$^h:: triggerFindAndReplace()

triggerFindAndReplace() {
 find := "Find and Replace" ; Window title of the Find and Replace window
 Send '^f'
 If WinWaitActive(find, "", 2) {
 WinSetAlwaysOnTop(1, find) ; Use 1 for On
; SoundBeep(1500)
 }
}

; Check the active window every 100 milliseconds
SetTimer CheckActiveWindow, 100

CheckActiveWindow() {
 find := "Find and Replace"
 activeWin := WinExist("A")

if activeWin and WinActive("ahk_exe SDLTradosStudio.exe") {
 if WinExist(find) {
 WinSetAlwaysOnTop(1, find) ; Turn on always on top if Trados Studio is active
 }
 } else {
 if WinExist(find) {
 WinSetAlwaysOnTop(0, find) ; Turn off always on top if Trados Studio is not active
 }
 }
}

#HotIf

Trados Studio > 6. AutoHotKey

Set a window Always On Top

Top Replies