Find&Replace window on top again

Question

Hello, possibly to @PaulFilkin, who helped me on this issue a few months ago, I'm in trouble again with the F&R window that remains stuck on top of any page in my PC. Could be after the last Trados update? 
 I tried to repeat the AutoHotkey actions that were recommended to me, but to no avail. In addition to that, my antivirus is telling me that the script has a virus. 
 Can someone help? 
 Thanks in advance

Paul · Accepted Answer

Valeria Maria Tafel 
 Try saving the file to your desktop first so you have the file... and save it with the .ahk extension, not as a .txt file. Once you've done that try to simply copy the file into your startup location. If you cannot do that then it could be due to at least these reasons: 
 
 The Startup folder is a protected system directory, and writing to it might require admin privileges. So make sure you are running with admin rights. 
 Windows Ransomware Protection (under Windows Security) includes Controlled Folder Access, which may block unauthorised programs from making changes to system folders like Startup. Check in Windows Security -> Virus & threat protection -> Ransomware protection if this feature is enabled. 
 Some third-party antivirus programs block unauthorised modifications to startup folders to prevent malware persistence. Your antivirus software may need to be configured to allow changes to the Startup folder. 
 
 Based on what you've said so far my money would be on what seems rather aggressive Antivirus settings.

Paul · Answer

Valeria Maria Tafel 
 To be honest I didn't keep track of this. So here's the one I have running in my own AHK... perhaps this is what you need? 
 ;------------------------------------------------------------------------------
; Ensure "Find and Replace" window is always on top when Trados Studio is active
; and not always on top when Trados Studio is not active
;------------------------------------------------------------------------------

#Requires AutoHotkey v2.0

global isOnTop := false

$^f:: triggerFindOrReplace("Find")
$^h:: triggerFindOrReplace("Replace")

triggerFindOrReplace(action) {
 global isOnTop
 findTitle := "Find and Replace"

 if (action = "Find") {
 Send '^f'
 } else if (action = "Replace") {
 Send '^h'
 }

 If WinWaitActive(findTitle " ahk_exe SDLTradosStudio.exe", "", 2) {
 ; Ensure Always on Top when the window is active in Studio
 if !isOnTop {
 WinSetAlwaysOnTop(1, findTitle " ahk_exe SDLTradosStudio.exe")
 isOnTop := true
 }
 }
}

; Check the active window every 100 milliseconds
SetTimer(CheckActiveWindow, 100)

CheckActiveWindow() {
 global isOnTop
 findTitle := "Find and Replace"

 if WinActive("ahk_exe SDLTradosStudio.exe") {
 if WinExist(findTitle " ahk_exe SDLTradosStudio.exe") {
 if !isOnTop {
 WinSetAlwaysOnTop(1, findTitle " ahk_exe SDLTradosStudio.exe")
 isOnTop := true
 }
 }
 } else {
 ; If Trados Studio is not active, remove the Always on Top status
 if isOnTop and WinExist(findTitle " ahk_exe SDLTradosStudio.exe") {
 WinSetAlwaysOnTop(0, findTitle " ahk_exe SDLTradosStudio.exe")
 isOnTop := false
 }
 }
}

Paul · Answer

Valeria Maria Tafel 
 Yes... I have seen your message. I just tested on my own machine and this same script is still working as well as it can. So, I had a play using a new AI tool I'm finding to be pretty good at AHK scripting and this one also works for me, but perhaps will be better in your circumstances: 
 ;------------------------------------------------------------------------------
; Ensure "Find and Replace" window is always on top when Trados Studio is active
; and not always on top when Trados Studio is not active. New Version 2.0
;------------------------------------------------------------------------------

#Requires AutoHotkey v2.0

; Global variable to track the "Always on Top" state
global isOnTop := false
global findTitle := "Find and Replace"

; Hotkeys for triggering Find or Replace
$^f:: TriggerFindOrReplace("Find")
$^h:: TriggerFindOrReplace("Replace")

TriggerFindOrReplace(action) {
 global isOnTop, findTitle
 static studioExe := "ahk_exe SDLTradosStudio.exe"

 ; Send the appropriate hotkey
 Send (action = "Find") ? "^f" : "^h"

 ; Wait for the Find and Replace window to appear, with error handling
 try {
 if WinWaitActive(findTitle " " studioExe, "", 2) {
 if !isOnTop {
 WinSetAlwaysOnTop(1, "A") ; Use "A" for active window
 isOnTop := true
 }
 }
 } catch {
 ; Optionally log failure or silently fail
 return
 }
}

; Timer to monitor active window state
SetTimer(CheckActiveWindow, 100)

CheckActiveWindow() {
 global isOnTop, findTitle
 static studioExe := "ahk_exe SDLTradosStudio.exe"

 try {
 ; Check if Trados Studio is the active application
 if WinActive(studioExe) {
 if WinExist(findTitle " " studioExe) && !isOnTop {
 WinSetAlwaysOnTop(1, findTitle " " studioExe)
 isOnTop := true
 }
 } else if isOnTop && WinExist(findTitle " " studioExe) {
 ; Remove Always on Top when Trados Studio is not active
 WinSetAlwaysOnTop(0, findTitle " " studioExe)
 isOnTop := false
 }
 } catch as e {
 ; Handle potential errors gracefully (e.g., window not found)
 isOnTop := false ; Reset state to avoid stale flags
 }
}

; Graceful exit handler
#SingleInstance Force
OnExit((*) => (SetTimer(CheckActiveWindow, 0))) ; Stop timer on exit 
 Give that a try and see if it works better for you?

Trados Studio > 6. AutoHotKey

Find&Replace window on top again

Top Replies