Translating OptionButtons in a Word file

Question

I have a .docx file which includes a questionnaire. The answers are chosen via radio buttons (see image below), but I can't get Trados to extract the text for these options.

Screenshot showing a .docx file with a questionnaire and radio buttons for ethnic origin options such as Asian, Asian - Bangladeshi, Asian - Chinese, Asian - Indian, and Asian - Pakistani.

I've tried selecting as many things as I can under 'embedded content' when preparing the files (Radio button, check box and man y others...), as well as every reasonable and unreasonable option under 'common', but it doesn't want to extract this text. In Word itself, to edit I have to use the Developer tab, click Design Mode, then right click on each answer, go to object, then 'Edit', not sure if this process is what's blocking Studio from extracting?

This is the properties info for one of the buttons:

Screenshot of the properties window for a radio button in a Word document, showing settings like Name, Caption, Font, ForeColor, and other properties.

I'm on Trados Studio 2021 SR2 Freelance edition.

Generated Image Alt-Text
[edited by: Trados AI at 11:39 AM (GMT 1) on 17 Apr 2024]

Paul · Answer

Elin Davies Lydia Simplicio 
 I guess you could use a macro to extract the values into Excel. Translate the Excel and then import back into Word with another macro. In principle it can work ;-) For example. I have this Word file: 
 
 I use this macro: 
 Sub ExportActiveXControlsToExcel()
 Dim xlApp As Object
 Dim xlBook As Object
 Dim xlSheet As Object
 Dim ctrl As Object
 Dim i As Integer

' Create a new Excel instance
 Set xlApp = CreateObject("Excel.Application")
 xlApp.Visible = True
 Set xlBook = xlApp.Workbooks.Add
 Set xlSheet = xlBook.Worksheets(1)

i = 1
 ' Loop through all ActiveX controls in the Word document
 For Each ctrl In ActiveDocument.InlineShapes
 If TypeName(ctrl.OLEFormat.Object) = "OptionButton" Then
 xlSheet.Cells(i, 1).Value = ctrl.OLEFormat.Object.Name
 xlSheet.Cells(i, 2).Value = ctrl.OLEFormat.Object.Caption
 i = i + 1
 End If
 Next ctrl

' AutoFit columns for better visibility
 xlSheet.Columns("A:B").AutoFit
End Sub 
 That gets me an Excel like this: 
 
 I translate that like this: 
 
 Then run this macro from the original Word file: 
 Sub ImportTranslatedCaptionsFromExcel()
 Dim xlApp As Object
 Dim xlBook As Object
 Dim xlSheet As Object
 Dim ctrl As Object
 Dim i As Integer
 Dim fd As Object
 Dim wsPath As String

' Create a FileDialog object as Open File dialog
 Set fd = Application.FileDialog(1) ' 1 = msoFileDialogOpen
 With fd
 .Title = "Select the Excel file with translations"
 .Filters.Clear
 .Filters.Add "Excel Files", "*.xls; *.xlsx; *.xlsm"
 If .Show = -1 Then ' -1 means the user pressed OK
 wsPath = .SelectedItems(1) ' Get the path of selected file
 Else
 ' Exit the Sub if no file is selected
 MsgBox "No file selected. Exiting...", vbExclamation
 Exit Sub
 End If
 End With

' Create a new Excel instance and open the workbook
 Set xlApp = CreateObject("Excel.Application")
 xlApp.Visible = True
 Set xlBook = xlApp.Workbooks.Open(wsPath)
 Set xlSheet = xlBook.Worksheets(1)

' Loop through all InlineShapes in the Word document
 For Each ctrl In ActiveDocument.InlineShapes
 If TypeName(ctrl.OLEFormat.Object) = "OptionButton" Then
 For i = 1 To xlSheet.Cells(xlSheet.Rows.Count, 1).End(-4162).Row ' -4162 corresponds to xlUp
 ' Match the control based on the name stored in Excel column A
 If ctrl.OLEFormat.Object.Name = xlSheet.Cells(i, 1).Value Then
 ' Update the Caption of the control with the translated text from Excel column B
 ctrl.OLEFormat.Object.Caption = xlSheet.Cells(i, 2).Value
 Exit For
 End If
 Next i
 End If
 Next ctrl

' Clean up
 xlBook.Close SaveChanges:=False
 xlApp.Quit
 Set xlSheet = Nothing
 Set xlBook = Nothing
 Set xlApp = Nothing
 Set fd = Nothing
End Sub 
 Now I have a Word file like this: 
 
 It's tricky as I think these are all ActiveX controls and I don't think Studio can read the captions. You'll almost certainly need to test thoroughly as I have no idea what else is in your file... mine is a simple example to test the theory.

Trados Studio > 2. Trados Studio

Translating OptionButtons in a Word file